ESP32 con WiFiManager, OLED, DHT22 y PHP

#include "oled.h"
#include "wm.h"
#include "dht22.h"
#include "php.h"

void setup() {
  Serial.begin(115200);
  Serial.println();
  Serial.println("Iniciando...");
  setupOled();
  mostrarOled("Iniciando...", "WiFiManager", "OLED", "ESP32");
  setupWM();
  setupDHT22();
}

void loop() {
  loopWM();
  loopDHT22();
  loopPHP();
}

#include <DHTesp.h>

DHTesp dht;
const int pinDHT = 33;

TempAndHumidity datosTH;
String temperatura;
String humedad;
float temperaturaFloat;
float humedadFloat;

unsigned long tiempoAnterior = 0;
const long intervalo = 10000;  // intervalo de 10seg

void setupDHT22() {
  dht.setup(pinDHT, DHTesp::DHT22);
}

void loopDHT22() {
  unsigned long tiempoActual = millis();
  if (tiempoActual - tiempoAnterior >= intervalo) {
    tiempoAnterior = tiempoActual;

    datosTH = dht.getTempAndHumidity();
    temperatura = String(datosTH.temperature, 2) + " C";
    humedad = String(datosTH.humidity, 1) + " %";
    temperaturaFloat = datosTH.temperature;
    humedadFloat = datosTH.humidity;
    Serial.print("Temperatura: ");
    Serial.print(temperatura);
    Serial.print("  Humedad: ");
    Serial.print(humedad);
    Serial.println();

    mostrarOled("ip: "+ipActual, "Temperatura: "+temperatura,"Humedad: "+humedad,"cvf");
  }
}

#include <U8g2lib.h>
U8G2_SSD1306_128X64_NONAME_F_HW_I2C u8g2(U8G2_R0);

void setupOled() {
  u8g2.begin();
}

void mostrarOled(String cad1="", String cad2="", String cad3="", String cad4="") {
  u8g2.clearBuffer();  // clear the internal memory
  u8g2.setFont(u8g2_font_6x10_tf);
  u8g2.setCursor(5, 14);
  u8g2.print(cad1);
  u8g2.setCursor(5, 30);
  u8g2.print(cad2);
  u8g2.setCursor(5, 46);
  u8g2.print(cad3);
  u8g2.setCursor(5, 62);
  u8g2.print(cad4);
  u8g2.sendBuffer();  // transfer internal memory to the display
}

#include <HTTPClient.h>
#include <ArduinoJson.h>

HTTPClient http;
//const char* serverUrl = "http://192.168.1.105/arduino/esp32_wifimanager_oled_dht22_php/php.php";
const char* serverUrl = "https://unicarlos.es/arduino/esp32_wifimanager_oled_dht22_php/php.php";

unsigned long lastTime = 0;
const long interval = 10000; // Intervalo de 10 segundos

void enviarDatosJSON(float temperatura, float humedad) {
  if (WiFi.status() == WL_CONNECTED) {
    // Crear documento JSON
    StaticJsonDocument<200> doc;
    doc["accion"] = "guardarTemHum";
    doc["temp"] = temperatura;
    doc["hum"] = humedad;

    // Serializar JSON
    String jsonString;
    serializeJson(doc, jsonString);

    // Configurar petición HTTP
    http.begin(serverUrl);
    http.addHeader("Content-Type", "application/json");

    // Enviar POST
    int httpCode = http.POST(jsonString);

    Serial.print("Enviando: ");
    Serial.println(jsonString);

    if (httpCode > 0) {
      String response = http.getString();
      Serial.print("Respuesta del servidor: ");
      Serial.println(response);
      
      // Procesar respuesta JSON
      StaticJsonDocument<200> respDoc;
      DeserializationError error = deserializeJson(respDoc, response);
      
      if (!error) {
        bool exito = respDoc["exito"];
        const char* mensaje = respDoc["mensaje"];
        Serial.print("Éxito: ");
        Serial.println(exito);
        Serial.print("Mensaje: ");
        Serial.println(mensaje);
      }
    } else {
      Serial.print("Error en HTTP request: ");
      Serial.println(httpCode);
    }

    http.end();
  }
}

void loopPHP() {
  unsigned long currentTime = millis();
  
  if (currentTime - lastTime >= interval) {
    lastTime = currentTime;
    enviarDatosJSON(temperaturaFloat, humedadFloat);
  }
}

#include "WiFi.h"
#include <WiFiManager.h>

const int pinCero = 0;
const int pinDos = 2;
WiFiManager wm;
String ipActual = "ninguna";

unsigned long tiempoPulsado = 0;
bool botonCeroPulsado = false;
bool estadoLedDos = LOW;
unsigned long tiempoRetardo = 0;

void setupWM() {
  pinMode(pinCero, INPUT);
  pinMode(pinDos, OUTPUT);
  digitalWrite(pinDos, LOW);
  // conectando
  Serial.println();
  Serial.println(WiFi.getHostname());
  digitalWrite(pinDos, HIGH);
  mostrarOled("SSID", WiFi.getHostname(), "Portal Cautivo", "192.168.4.1");
  if (wm.autoConnect(WiFi.getHostname(), "")) {
    IPAddress ip = WiFi.localIP();
    ipActual = ip.toString();
    mostrarOled("IP: " + ipActual);
    digitalWrite(pinDos, LOW);
  } else {
    Serial.println("Ha fallado la conexión");
  }
}

void loopWM() {
  if (digitalRead(pinCero) == LOW) {
    if (!botonCeroPulsado) {
      tiempoPulsado = millis();
      botonCeroPulsado = true;
      Serial.println("Boton boot pulsado");
      mostrarOled("Boton 0 pulsado", "", "", "");
    }

    int segundos = (millis() - tiempoPulsado) / 1000;
    mostrarOled("Boton 0 pulsado", "Tiempo: " + String(segundos) + " s", "Restante: " + String(3 - segundos) + " s");

    // Si el botón ha sido presionado por menos de 3 segundos, parpadea el LED
    if (millis() - tiempoPulsado < 3000) {
      if (millis() - tiempoRetardo >= 200) {  // Parpadea cada 500 ms
        estadoLedDos = !estadoLedDos;
        digitalWrite(pinDos, estadoLedDos);
        tiempoRetardo = millis();
      }
    } else {
      // Si el botón ha sido presionado por más de 3 segundos, mantén el LED encendido
      digitalWrite(pinDos, HIGH);
      mostrarOled("", "Reseteando WiFi...", "", "");
      wm.resetSettings();  // borra los datos de la memoria interna (SSID y contraseña)
      ESP.restart();
    }
  } else {
    if (botonCeroPulsado) {
      digitalWrite(pinDos, LOW);
      botonCeroPulsado = false;
      mostrarOled("IP: " + ipActual);
    }
  }
}

<?php
header('Content-Type: application/json');

// Función para enviar respuestas JSON
function enviarRespuesta($exito, $mensaje, $datos = null) {
    $respuesta = [
        'exito' => $exito,
        'mensaje' => $mensaje
    ];
    
    if ($datos !== null) {
        $respuesta['datos'] = $datos;
    }
    
    echo json_encode($respuesta);
    exit;
}

// Verificar que sea método POST
if ($_SERVER['REQUEST_METHOD'] !== 'POST') {
    enviarRespuesta(false, 'Método no permitido');
}

// Obtener y decodificar JSON recibido
$jsonData = file_get_contents('php://input');
$data = json_decode($jsonData, true);

// Verificar JSON válido
if ($data === null) {
    enviarRespuesta(false, 'JSON inválido');
}

// Verificar acción y datos requeridos
if (!isset($data['accion']) || $data['accion'] !== 'guardarTemHum' ||
    !isset($data['temp']) || !isset($data['hum'])) {
    enviarRespuesta(false, 'Datos incompletos o acción inválida');
}

// Preparar nuevo registro
$registro = [
    'temperatura' => $data['temp'],
    'humedad' => $data['hum'],
    'fecha_hora' => date('Y-m-d H:i:s')
];

// Nombre del archivo JSON
$archivo = 'json.json';

// Leer datos existentes o crear array vacío
$datosExistentes = [];
if (file_exists($archivo)) {
    $contenido = file_get_contents($archivo);
    if ($contenido) {
        $datosExistentes = json_decode($contenido, true) ?? [];
    }
}

// Añadir nuevo registro
$datosExistentes[] = $registro;

// Mantener solo los últimos 10 registros
if (count($datosExistentes) > 10) {
    array_shift($datosExistentes);
}

// Guardar en archivo
if (file_put_contents($archivo, json_encode($datosExistentes, JSON_PRETTY_PRINT))) {
    enviarRespuesta(true, 'Datos guardados correctamente', $registro);
} else {
    enviarRespuesta(false, 'Error al guardar los datos');
}
?>